All about flooble | fun stuff | Get a free chatterbox | Free JavaScript | Avatars
 perplexus dot info

 Octagon in a Circle (Posted on 2004-10-25)
The octagon ABCDEFGH is inscribed in a circle, with the vertices around the circumference in the given order. Given that the polygon ACEG is a square of area 5 and the polygon BDFH is a rectangle of area 4, find the maximum possible area of the octagon.

 No Solution Yet Submitted by Victor Zapana Rating: 3.5000 (2 votes)

Comments: ( Back to comment list | You must be logged in to post comments.)
 solution | Comment 1 of 6

The square has a side equal to sqrt(5) and therefore a diagonal of length sqrt(10), which is also the diameter of the circle, whose radius is therefore sqrt(10)/2.

If rectangle BDFH has shorter and longer sides x and y respectively, then xy = 4 and y=sqrt(10-x^2).  This can be solved numerically and the numbers come out to sqrt(2) and 2*sqrt(2), which can be verified by plugging into the two equations.  These subtend arcs of 53.13... and 126.86... degrees along the circle.

The only variable is the orientation of rectangle BDFH relative to square ACEG.   The short sides of the rectangle could either bracket opposite corners of the square, or be bracketed by two opposite pairs of corners of the square.  In the former case, triangles are formed on all four sides of the square to complete the octagon and Heron's formula can be used to compute their areas, once the sides have been computed as chords of the circle based on the central angle (arc length) separating them from the vertices of the square.  In the latter case Brahmgupta's formula can be used as two quadrilaterals are appended to the square to make the octagon, and these quadrilaterals are inscibed in the circle.

The following program tabulates the total area (four triangles plus 5 or two quadrilaterals plus 5) at 2-degree intervals and at two local maxima for the arc separating a corner of the rectangle from a corner of the square:

DECLARE FUNCTION asin# (x#)
DEFDBL A-Z
CLS
pi = ATN(1#) * 4#
r = SQR(10) / 2

x = 2
DO
xP = x
x = 4 / SQR(10 - x * x)
LOOP UNTIL x = xP

PRINT x, 4 / x

sep1 = 2 * asin(x / 2 / r) * 180 / pi
sep2 = 180 - sep1
PRINT sep1, sep2

FOR a1 = 1 TO sep1 STEP 2
b1 = sep1 - a1
a2 = 90 - a1
b2 = 90 - b1
chord1 = 2 * r * SIN(a1 / 2 * pi / 180)
chord2 = 2 * r * SIN((a2 / 2) * pi / 180)
s = .5 * (chord1 + chord2 + SQR(5))
area = SQR(s * (s - chord1) * (s - chord2) * (s - SQR(5)))
chord1 = 2 * r * SIN(b1 / 2 * pi / 180)
chord2 = 2 * r * SIN(b2 / 2 * pi / 180)
s = .5 * (chord1 + chord2 + SQR(5))
area = 2 * (area + SQR(s * (s - chord1) * (s - chord2) * (s - SQR(5))))
area = area + 5
PRINT USING "### ##.#########"; a1; area
NEXT a1
a1 = sep1 / 2
b1 = sep1 - a1
a2 = 90 - a1
b2 = 90 - b1
chord1 = 2 * r * SIN(a1 / 2 * pi / 180)
chord2 = 2 * r * SIN((a2 / 2) * pi / 180)
s = .5 * (chord1 + chord2 + SQR(5))
area = SQR(s * (s - chord1) * (s - chord2) * (s - SQR(5)))
chord1 = 2 * r * SIN(b1 / 2 * pi / 180)
chord2 = 2 * r * SIN(b2 / 2 * pi / 180)
s = .5 * (chord1 + chord2 + SQR(5))
area = 2 * (area + SQR(s * (s - chord1) * (s - chord2) * (s - SQR(5))))
area = area + 5
PRINT a1; area

FOR a1 = 1 TO 45 - sep1 / 2 STEP 2
chord1 = 2 * r * SIN(a1 / 2 * pi / 180)
chord2 = 2 * r * SIN(sep1 / 2 * pi / 180)
chord3 = 2 * r * SIN((90 - a1 - sep1) / 2 * pi / 180)
s = .5 * (chord1 + chord2 + chord3 + SQR(5))
area = 2 * SQR((s - chord1) * (s - chord2) * (s - chord3) * (s - SQR(5))) + 5

PRINT USING "### ##.#########"; a1; area
NEXT a1
a1 = 45 - sep1 / 2
chord1 = 2 * r * SIN(a1 / 2 * pi / 180)
chord2 = 2 * r * SIN(sep1 / 2 * pi / 180)
chord3 = 2 * r * SIN((90 - a1 - sep1) / 2 * pi / 180)
s = .5 * (chord1 + chord2 + chord3 + SQR(5))
area = 2 * SQR((s - chord1) * (s - chord2) * (s - chord3) * (s - SQR(5))) + 5
PRINT a1; area

FUNCTION asin (x)
asin = ATN(x / SQR(1 - x * x))
END FUNCTION

The output is:

` 1.414213562373095           2.82842712474619 53.13010235415598           126.869897645844  1  6.051443390  3  6.148785077  5  6.238635417  7  6.320884940  9  6.395433439 11  6.462190087 13  6.521073552 15  6.572012093 17  6.614943650 19  6.649815917 21  6.676586408 23  6.695222506 25  6.705701507 27  6.708010644 29  6.702147104 31  6.688118029 33  6.665940513 35  6.635641575 37  6.597258130 39  6.550836942 41  6.496434568 43  6.434117290 45  6.363961031 47  6.286051265 49  6.200482915 51  6.107360231 53  6.006796669 26.56505117707799  6.70820393249937  1  6.008497746  3  6.024112280  5  6.037869919  7  6.049753899  9  6.059749743 11  6.067845273 13  6.074030624 15  6.078298262 17  6.080642986 18.43494882292201  6.081138830084191`

where the first line shows the lengths of the sides of the rectangle, and the second shows the total arc cut by these sides as chords.

The maximum area shows up as  6.081138830084191, when the rectangle's short edges do not bracket a corner of the square, and are centered on one of the sides of the square, at which point the corner of each rectangle is 18.43... degrees of arc from a corner of the square.

P.S., of course 6.708... > 6.081..., and the answer with the short side of the rectangle straddling a corner of the square is the largest, as per later posts.

Edited on October 25, 2004, 8:54 pm
 Posted by Charlie on 2004-10-25 16:00:08

 Search: Search body:
Forums (0)