Start with a unit circle and draw four line segments each of length L. The first line is a chord: it begins and ends on the circle. Subsequent lines start from the midpoint of the previous line and end on the circle. If the fourth line ends where the first line begins, what is L?
Note that this sketch is an approximation.
I am trying a different approach and setting the internal quadrilateral AHIJ on a coordinate grid. I have
A(0,0)
J(2,0)
I(2-t, sqrt[1-t^2])
H({2-t-sqrt[(4t-1)/(5-4t)]*sqrt[1-t^2]}/2, {sqrt[1-t^2]-sqrt[(4t-1)/(5-4t)]*(2-t)}/2)
Then I extend AH to B, HI to C, and IJ to D by using the midpoint formula. After that I wrote equations for the perpendictular bisectors of AB, AC, and AD. All three lines must intersectinthe same point. (I am omitting the details.)
I could not get any further analytically, simply from the complexity of the system. But I was able to run a numeric simulation in UBASIC:
10 Tlow=0.3
11 Thigh=0.5
12 Count=0
20 T=(Tlow+Thigh)/2
21 Count=Count+1
101 K=sqrt((4*T-1)/(5-4*T))
111 Ix=2-T
112 Iy=sqrt(1-T*T)
121 Hx=(Ix-K*Iy)/2
122 Hy=(Iy+K*Ix)/2
125 ' print Hx;Hy;Ix;Iy
131 Bx=2*Hx
132 By=2*Hy
141 Cx=2*Ix-Hx
142 Cy=2*Iy-Hy
151 Dx=T+2
152 Dy=-Iy
160 ' print Bx;By,Cx;Cy,Dx;Dy
200 Denom=2*Bx*Dy-2*By*Dx
201 Xnum=Dy*(Bx*Bx+By*By)-By*(Dx*Dx+Dy*Dy)
202 Ynum=Bx*(Dx*Dx+Dy*Dy)-Dx*(Bx*Bx+By*By)
211 X=Xnum/Denom
212 Y=Ynum/Denom
220 Radius=sqrt(X*X+Y*Y)
230 Delta=2*Cx*X+2*Cy*Y-Cx*Cx-Cy*Cy
300 print T,Radius,Delta:print
310 if Delta>0 then Thigh=T else Tlow=T
320 if Count<40 then 20
This converges on a radius of 1.446685313104. This corresponds to a chord length of 1.382470660263 when the circle has a unit radius. This agrees with other numeric simulations.
Another approach
