A prominent politician recently proposed, as part of our SDI, to place a defensive satellite in geosynchronous orbit directly above Washington, D.C.

What if anything is wrong with his suggestion?

(In reply to Impossible Orbit by Larry)

A satellite in orbit must have the earth's center at one of the foci of its orbit.  If it's a circular orbit, this is the center of the orbit. So by staying at 39 degrees north, the latitude of D.C., the satellite would be following a lesser circle rather than a great circle.  With a circular orbit 26,000 miles out, it would be over 16,000 miles above the plane of the equator.  As the radius of the earth is about 4,000 miles, the plane of this "orbit" would not even include any of the earth.

An orbit could be made in which the satellite could be at approximately the longitude of Washington while shuttling between 39 deg north and 39 deg south over the course of a day. It could not stay at exactly the same longitude, even with a circular orbit, but rather traverse a figure-8, because it travels in its circular orbit one degree of great circle every four minutes. But at it's northernmost and southernmost the meridians of longitude are spaced closer together so 1 degree on the great circle spans 1/cos 39 = 1.29 degrees of longitude, beating out the earth's surface passing below.  Then when it crosses the equator part of the 1 deg/4 min goes into a north-south component instead of east west, so only cos39 = .777 degrees of longitude get covered in 4 minutes allowing the earth's surface to speed by this time.

Such a satellite's progress would be:

  0.0   0.0
  6.3  -2.2
 12.4  -4.2
 18.3  -5.8
 23.9  -6.9
 28.8  -7.2
 33.0  -6.6
 36.3  -5.1
 38.3  -2.8
 39.0   0.0
 38.3   2.8
 36.3   5.1
 33.0   6.6
 28.8   7.2
 23.9   6.9
 18.3   5.8
 12.4   4.2
  6.3   2.2
  0.0   0.0
 -6.3  -2.2
-12.4  -4.2
-18.3  -5.8
-23.9  -6.9
-28.8  -7.2
-33.0  -6.6
-36.3  -5.1
-38.3  -2.8
-39.0   0.0
-38.3   2.8
-36.3   5.1
-33.0   6.6
-28.8   7.2
-23.9   6.9
-18.3   5.8
-12.4   4.2
 -6.3   2.2
 -0.0   0.0

where the left column shows the latitude and the right shows the deviation in longitude from that of Washington, DC; both in degrees.  So it would barely stay in the time zone, which has a width of 15 degrees.  As the difference in latitude gets to be 78 degrees, at that point the satellite would be less than 12 degrees above Washington's southern horizon.  (It's less than the complement of 78 due to parallax; the satellite is not infinitely far away, and in fact its parallax would be about 8 degrees, making it only about 4 degrees above the southern horizon at DC.)

The main part of the program to produce the above table is:

incl = 39
FOR clon = 0 TO 360 STEP 10
  lat = arcsine(sine(clon) * sine(incl))
  lon = norm(sign(norm(clon)) * arccosine(cosine(clon) / cosine(lat)) - clon)
  PRINT USING " ###.#"; lat; lon
NEXT

The subject came up in the "Marilyn is Wrong" website, where I had a comment about it.

For those interested, the full program is:

DECLARE FUNCTION sign# (x#)
DECLARE FUNCTION arccosine# (x#)
DECLARE FUNCTION arcsine# (x#)
DECLARE FUNCTION cosine# (x#)
DECLARE FUNCTION norm# (x#)
DECLARE FUNCTION sine# (x#)
DEFDBL A-Z
DIM SHARED dr, pi
dr = ATN(1) / 45
pi = ATN(1) * 4

CLS
incl = 39
FOR clon = 0 TO 360 STEP 10
  lat = arcsine(sine(clon) * sine(incl))
  lon = norm(sign(norm(clon)) * arccosine(cosine(clon) / cosine(lat)) - clon)
  PRINT USING " ###.#"; lat; lon
NEXT

FUNCTION arccosine (x)
 arccosine = 90 - arcsine(x)
END FUNCTION

FUNCTION arcsine (x)
 IF ABS(x) = 1 THEN
  ang = pi * SGN(x) / 2
 ELSE
  ang = ATN(x / SQR(1 - x * x))
 END IF
 arcsine = ang / dr
END FUNCTION

FUNCTION cosine (x)
 cosine = sine(90 - x)
END FUNCTION

FUNCTION norm (x)
 c = x / 360 - INT(x / 360)
 IF c > .5 THEN c = c - 1
 norm = c * 360
END FUNCTION

FUNCTION sign (x)
 sign = SGN(SGN(x) + .5)
END FUNCTION

FUNCTION sine (x)
 sine = SIN(x * dr)
END FUNCTION

 

Posted by Charlie on 2004-06-05 15:16:10